Si comme moi :
- tu privilégies les performances à l'espace de stockage
- tu stockes sur disque interne ou extension M2
Alors tu devrais sérieusement considérer la création de tes propres ffpkg - ceux de la scène étant douteux. À utiliser avec ShadowMount+.
Tout d'abord je tiens à préciser que l'époque à laquelle on était obligé d'installer certains jeux sur disque USB est révolue. On peut tout faire tourner sur disque interne / m2. C'est un grand avantage pour les performances, l'USB3 n'étant pas suffisant pour certains jeux qui stream agressivement les assets. Après m'être pris la tête avec TLOU je pense avoir trouvé la bonne procédure. Je la partage ici au cas où ça peut servir à quelqu'un d'autre 
La mise en place :
-1-
Installer la dernière version de UFS2Tool https://github.com/S...S2Tool/releases, p. ex. dans C:\Tools\UFS2Tool
-2-
Créer un dossier pour le build, p. ex. C:\build
-3-
Déposer dans ce dossier le fichier bat make_ffpkg.bat ci-joint (adapter les constantes si installation ailleurs que dans C:\Tools\UFS2Tool)
---
Pour convertir un jeu :
-1-
Placer le dossier "raw dump" du jeu dans le dossier build. Attention il ne doit pas y avoir plusieurs niveaux de dossier ; dans ce dossier on trouve directement eboot.bin à la racine. Exemple de nom de dossier : PPSA03845-Dead Space. On se retrouve avec C:\build\PPSA03845-Dead Space\eboot.bin
-2-
Glisser le dossier de jeu sur make_ffpkg.bat
-3-
Valider l'élévation de droits et attendre le message SUCCES
PS
Je ne trouve plus l'option pièce jointe (l'éditeur de message du forum est en PLS), voici le contenu de make_ffpkg.bat :
@echo off
setlocal EnableExtensions DisableDelayedExpansion
set "UFS2TOOL=C:\Tools\UFS2Tool\UFS2Tool.exe"
if "%~1"=="" (
echo Glisse un dossier de dump PS5 sur ce fichier BAT.
pause
exit /b 1
)
set "INPUT=%~1"
set "NAME=%~n1"
set "DIR=%~dp1"
set "OUTPUT=%DIR%%NAME%.ffpkg"
set "ERRORLOG=%DIR%ERROR.log"
if exist "%ERRORLOG%" del /f /q "%ERRORLOG%" >nul 2>&1
echo.
echo Creation du FFPKG :
echo "%OUTPUT%"
echo.
"%UFS2TOOL%" newfs -O 2 -b 65536 -f 65536 -m 0 -S 4096 -i 262144 -D "%INPUT%" "%OUTPUT%"
set "EXITCODE=%ERRORLEVEL%"
if not "%EXITCODE%"=="0" (
(
echo ERREUR FFPKG BUILD
echo Date: %DATE% %TIME%
echo Source: "%INPUT%"
echo Destination: "%OUTPUT%"
echo ExitCode: %EXITCODE%
) > "%ERRORLOG%"
echo.
echo ECHEC. Log cree :
echo "%ERRORLOG%"
pause
exit /b %EXITCODE%
)
echo.
echo SUCCES :
echo "%OUTPUT%"
echo.
pause
exit /b 0
Ce message a été modifié par calamita - 17 May 2026 - 12:08.
